mirror of
https://github.com/espressif/binutils-gdb.git
synced 2025-08-23 22:09:19 +08:00
73cc72729a
This patch moves the gdb/gnulib subdirectory to the top level. It adjusts the top-level build system to build gnulib when necessary, and changes gdb to use this. However, gdbserver still builds its own copy of gnulib, just from the new source location. A small hack was needed to ensure that gnulib is only built when gdb is enabled. The Makefile only provides an ordering -- the directory must be mentioned in configdirs to actually be compiled at all. Most of the patch is just a "git mv" of gnulib, though a few minor path adjustments were needed in some files there. Tested by the buildbot. ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * MAINTAINERS: Add gnulib. * gnulib: New directory, move from gdb/gnulib. * configure.ac (host_libs): Add gnulib. * configure: Rebuild. * Makefile.def (host_modules, dependencies): Add gnulib. * Makefile.in: Rebuild. gdb/ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * gnulib: Move directory to top-level. * configure.ac: Don't configure gnulib. * configure: Rebuild. * common/common-defs.h: Use new path to gnulib. * Makefile.in (GNULIB_BUILDDIR): Now ../gnulib. (GNULIB_H): Remove. (INCGNU): Look in new gnulib location. (HFILES_NO_SRCDIR): Remove gnulib files. (SUBDIR, REQUIRED_SUBDIRS): Remove gnulib. (generated_files): Remove GNULIB_H. ($(LIBGNU), all-lib): Remove targets. (distclean): Don't mention GNULIB_BUILDDIR. ($(GNULIB_BUILDDIR)/Makefile): Remove target. gdb/gdbserver/ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * configure.ac: Use new path to gnulib. * configure: Rebuild. * Makefile.in (INCGNU, $(GNULIB_BUILDDIR)/Makefile): Use new path to gnulib. gnulib/ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * update-gnulib.sh: Adjust paths. * Makefile.in: Adjust paths. * configure.ac: Adjust paths. Use ACX_LARGEFILE. * configure: Rebuild.
84 lines
3.0 KiB
Plaintext
84 lines
3.0 KiB
Plaintext
# signal_h.m4 serial 18
|
|
dnl Copyright (C) 2007-2016 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN([gl_SIGNAL_H],
|
|
[
|
|
AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
|
|
AC_REQUIRE([gl_CHECK_TYPE_SIGSET_T])
|
|
gl_NEXT_HEADERS([signal.h])
|
|
|
|
# AIX declares sig_atomic_t to already include volatile, and C89 compilers
|
|
# then choke on 'volatile sig_atomic_t'. C99 requires that it compile.
|
|
AC_CHECK_TYPE([volatile sig_atomic_t], [],
|
|
[HAVE_TYPE_VOLATILE_SIG_ATOMIC_T=0], [[
|
|
#include <signal.h>
|
|
]])
|
|
|
|
dnl Ensure the type pid_t gets defined.
|
|
AC_REQUIRE([AC_TYPE_PID_T])
|
|
|
|
AC_REQUIRE([AC_TYPE_UID_T])
|
|
|
|
dnl Persuade glibc <signal.h> to define sighandler_t.
|
|
AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
|
|
AC_CHECK_TYPE([sighandler_t], [], [HAVE_SIGHANDLER_T=0], [[
|
|
#include <signal.h>
|
|
]])
|
|
|
|
dnl Check for declarations of anything we want to poison if the
|
|
dnl corresponding gnulib module is not in use.
|
|
gl_WARN_ON_USE_PREPARE([[#include <signal.h>
|
|
]], [pthread_sigmask sigaction
|
|
sigaddset sigdelset sigemptyset sigfillset sigismember
|
|
sigpending sigprocmask])
|
|
])
|
|
|
|
AC_DEFUN([gl_CHECK_TYPE_SIGSET_T],
|
|
[
|
|
AC_CHECK_TYPES([sigset_t],
|
|
[gl_cv_type_sigset_t=yes], [gl_cv_type_sigset_t=no],
|
|
[[
|
|
#include <signal.h>
|
|
/* Mingw defines sigset_t not in <signal.h>, but in <sys/types.h>. */
|
|
#include <sys/types.h>
|
|
]])
|
|
if test $gl_cv_type_sigset_t != yes; then
|
|
HAVE_SIGSET_T=0
|
|
fi
|
|
])
|
|
|
|
AC_DEFUN([gl_SIGNAL_MODULE_INDICATOR],
|
|
[
|
|
dnl Use AC_REQUIRE here, so that the default settings are expanded once only.
|
|
AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
|
|
gl_MODULE_INDICATOR_SET_VARIABLE([$1])
|
|
dnl Define it also as a C macro, for the benefit of the unit tests.
|
|
gl_MODULE_INDICATOR_FOR_TESTS([$1])
|
|
])
|
|
|
|
AC_DEFUN([gl_SIGNAL_H_DEFAULTS],
|
|
[
|
|
GNULIB_PTHREAD_SIGMASK=0; AC_SUBST([GNULIB_PTHREAD_SIGMASK])
|
|
GNULIB_RAISE=0; AC_SUBST([GNULIB_RAISE])
|
|
GNULIB_SIGNAL_H_SIGPIPE=0; AC_SUBST([GNULIB_SIGNAL_H_SIGPIPE])
|
|
GNULIB_SIGPROCMASK=0; AC_SUBST([GNULIB_SIGPROCMASK])
|
|
GNULIB_SIGACTION=0; AC_SUBST([GNULIB_SIGACTION])
|
|
dnl Assume proper GNU behavior unless another module says otherwise.
|
|
HAVE_POSIX_SIGNALBLOCKING=1; AC_SUBST([HAVE_POSIX_SIGNALBLOCKING])
|
|
HAVE_PTHREAD_SIGMASK=1; AC_SUBST([HAVE_PTHREAD_SIGMASK])
|
|
HAVE_RAISE=1; AC_SUBST([HAVE_RAISE])
|
|
HAVE_SIGSET_T=1; AC_SUBST([HAVE_SIGSET_T])
|
|
HAVE_SIGINFO_T=1; AC_SUBST([HAVE_SIGINFO_T])
|
|
HAVE_SIGACTION=1; AC_SUBST([HAVE_SIGACTION])
|
|
HAVE_STRUCT_SIGACTION_SA_SIGACTION=1;
|
|
AC_SUBST([HAVE_STRUCT_SIGACTION_SA_SIGACTION])
|
|
HAVE_TYPE_VOLATILE_SIG_ATOMIC_T=1;
|
|
AC_SUBST([HAVE_TYPE_VOLATILE_SIG_ATOMIC_T])
|
|
HAVE_SIGHANDLER_T=1; AC_SUBST([HAVE_SIGHANDLER_T])
|
|
REPLACE_PTHREAD_SIGMASK=0; AC_SUBST([REPLACE_PTHREAD_SIGMASK])
|
|
REPLACE_RAISE=0; AC_SUBST([REPLACE_RAISE])
|
|
])
|