mirror of
https://github.com/espressif/binutils-gdb.git
synced 2025-08-24 14:22:27 +08:00
73cc72729a
This patch moves the gdb/gnulib subdirectory to the top level. It adjusts the top-level build system to build gnulib when necessary, and changes gdb to use this. However, gdbserver still builds its own copy of gnulib, just from the new source location. A small hack was needed to ensure that gnulib is only built when gdb is enabled. The Makefile only provides an ordering -- the directory must be mentioned in configdirs to actually be compiled at all. Most of the patch is just a "git mv" of gnulib, though a few minor path adjustments were needed in some files there. Tested by the buildbot. ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * MAINTAINERS: Add gnulib. * gnulib: New directory, move from gdb/gnulib. * configure.ac (host_libs): Add gnulib. * configure: Rebuild. * Makefile.def (host_modules, dependencies): Add gnulib. * Makefile.in: Rebuild. gdb/ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * gnulib: Move directory to top-level. * configure.ac: Don't configure gnulib. * configure: Rebuild. * common/common-defs.h: Use new path to gnulib. * Makefile.in (GNULIB_BUILDDIR): Now ../gnulib. (GNULIB_H): Remove. (INCGNU): Look in new gnulib location. (HFILES_NO_SRCDIR): Remove gnulib files. (SUBDIR, REQUIRED_SUBDIRS): Remove gnulib. (generated_files): Remove GNULIB_H. ($(LIBGNU), all-lib): Remove targets. (distclean): Don't mention GNULIB_BUILDDIR. ($(GNULIB_BUILDDIR)/Makefile): Remove target. gdb/gdbserver/ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * configure.ac: Use new path to gnulib. * configure: Rebuild. * Makefile.in (INCGNU, $(GNULIB_BUILDDIR)/Makefile): Use new path to gnulib. gnulib/ChangeLog 2019-06-14 Tom Tromey <tom@tromey.com> * update-gnulib.sh: Adjust paths. * Makefile.in: Adjust paths. * configure.ac: Adjust paths. Use ACX_LARGEFILE. * configure: Rebuild.
39 lines
1.6 KiB
Plaintext
39 lines
1.6 KiB
Plaintext
# double-slash-root.m4 serial 4 -*- Autoconf -*-
|
|
dnl Copyright (C) 2006, 2008-2016 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
AC_DEFUN([gl_DOUBLE_SLASH_ROOT],
|
|
[
|
|
AC_REQUIRE([AC_CANONICAL_HOST])
|
|
AC_CACHE_CHECK([whether // is distinct from /], [gl_cv_double_slash_root],
|
|
[ if test x"$cross_compiling" = xyes ; then
|
|
# When cross-compiling, there is no way to tell whether // is special
|
|
# short of a list of hosts. However, the only known hosts to date
|
|
# that have a distinct // are Apollo DomainOS (too old to port to),
|
|
# Cygwin, and z/OS. If anyone knows of another system for which // has
|
|
# special semantics and is distinct from /, please report it to
|
|
# <bug-gnulib@gnu.org>.
|
|
case $host in
|
|
*-cygwin | i370-ibm-openedition)
|
|
gl_cv_double_slash_root=yes ;;
|
|
*)
|
|
# Be optimistic and assume that / and // are the same when we
|
|
# don't know.
|
|
gl_cv_double_slash_root='unknown, assuming no' ;;
|
|
esac
|
|
else
|
|
set x `ls -di / // 2>/dev/null`
|
|
if test "$[2]" = "$[4]" && wc //dev/null >/dev/null 2>&1; then
|
|
gl_cv_double_slash_root=no
|
|
else
|
|
gl_cv_double_slash_root=yes
|
|
fi
|
|
fi])
|
|
if test "$gl_cv_double_slash_root" = yes; then
|
|
AC_DEFINE([DOUBLE_SLASH_IS_DISTINCT_ROOT], [1],
|
|
[Define to 1 if // is a file system root distinct from /.])
|
|
fi
|
|
])
|