[gdb/testsuite] Add gdb.dwarf2/debug-names-tu.exp

Add a test-case gdb.dwarf2/debug-names-tu.exp, that uses the dwarf assembler
to specify a .debug_names index with the TU list referring to a TU from the
.debug_types section.

This is intended to produce something similar to:
...
$ gcc -g -fdebug-types-section ~/hello.c -gdwarf-4
$ gdb-add-index -dwarf-5 a.out
...

Tested on x86_64-linux.

gdb/testsuite/gdb.dwarf2/debug-names-tu.exp

@@ -0,0 +1,93 @@
+# Copyright 2022 Free Software Foundation, Inc.
+
+# This program is free software; you can redistribute it and/or modify
+# it under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 3 of the License, or
+# (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program.  If not, see <http://www.gnu.org/licenses/>.
+
+load_lib dwarf.exp
+
+# This test can only be run on targets which support DWARF-2 and use gas.
+if {![dwarf2_support]} {
+    return 0
+}
+
+standard_testfile _start.c debug-names.S
+
+set func_info_vars \
+    [get_func_info _start [list debug additional_flags=-nostartfiles]]
+
+# Create the DWARF.
+set asm_file [standard_output_file $srcfile2]
+Dwarf::assemble {
+    filename $asm_file
+    add_dummy_cus 0
+} {
+    global func_info_vars
+    foreach var $func_info_vars {
+	global $var
+    }
+
+    cu { label cu_label } {
+	compile_unit {{language @DW_LANG_C}} {
+	    subprogram {
+		{DW_AT_name _start}
+		{DW_AT_low_pc $_start_start DW_FORM_addr}
+		{DW_AT_high_pc $_start_end DW_FORM_addr}
+	    }
+	}
+    }
+
+    tu { label tu_label } 0x8ece66f4224fddb3 "" {
+	type_unit {} {
+	    declare_labels int_type
+
+	    structure_type {
+		{name struct_with_int_member}
+		{byte_size 4 sdata}
+	    } {
+		member {
+		    {name member}
+		    {type :$int_type}
+		}
+	    }
+	    int_type: base_type {
+		{name int}
+		{encoding @DW_ATE_signed}
+		{byte_size 4 sdata}
+	    }
+	}
+    }
+
+    debug_names {} {
+	cu cu_label
+	tu tu_label
+	name _start subprogram cu_label 0xEDDB6232
+	name struct_with_int_member structure_type tu_label 0x53A2AE86
+    }
+}
+
+if [prepare_for_testing "failed to prepare" $testfile "${asm_file} ${srcfile}" \
+	[list additional_flags=-nostartfiles]] {
+    return -1
+}
+
+# Verify that .debug_names section is not ignored.
+set index [have_index $binfile]
+gdb_assert { [string equal $index "debug_names"] } ".debug_names used"
+
+# Verify that we can find the type in the type unit.
+set re \
+    [multi_line \
+	 "type = struct struct_with_int_member {" \
+	 "    int member;" \
+	 "}"]
+gdb_test "ptype struct struct_with_int_member" $re

gdb/testsuite/lib/dwarf.exp

@@ -1560,6 +1560,7 @@ namespace eval Dwarf {
 	set _cu_is_fission 0
 	set section ".debug_types"
 	set _abbrev_section ".debug_abbrev"
+	set label ""
 
 	foreach { name value } $options {
 	    switch -exact -- $name {
@@ -1567,6 +1568,7 @@ namespace eval Dwarf {
 		version { set _cu_version $value }
 		addr_size { set _cu_addr_size $value }
 		fission { set _cu_is_fission $value }
+		label { set label $value }
 		default { error "unknown option $name" }
 	    }
 	}
@@ -1593,6 +1595,11 @@ namespace eval Dwarf {
 	set start_label [_compute_label "cu${cu_num}_start"]
 	set end_label [_compute_label "cu${cu_num}_end"]
 
+	if { $label != "" } {
+	    upvar $label my_label
+	    set my_label $_cu_label
+	}
+
 	define_label $_cu_label
 	if {$is_64} {
 	    _op .4byte 0xffffffff
@@ -2991,6 +2998,12 @@ namespace eval Dwarf {
 	    variable _debug_names_cus
 	    lappend _debug_names_cus $cu
 	}
+       variable _debug_names_tus
+       set _debug_names_tus []
+       proc _debug_names_tu { tu } {
+	   variable _debug_names_tus
+	   lappend _debug_names_tus $tu
+       }
 	variable _debug_names
 	set _debug_names []
 	proc _debug_names_name { name tag cu hash } {
@@ -2999,13 +3012,14 @@ namespace eval Dwarf {
 	    lappend _debug_names [list $name $tag $cu $hash $entry_pool_offset]
 	}
 	with_override Dwarf::cu Dwarf::_debug_names_cu {
+	with_override Dwarf::tu Dwarf::_debug_names_tu {
 	with_override Dwarf::name Dwarf::_debug_names_name {
 	    uplevel $body
-	}}
+	}}}
 
 	# Header - CU / TU / foreign TU count.
 	_op .4byte [llength $_debug_names_cus] "Comp_unit_count"
-	_op .4byte 0 "Local_type_unit_count"
+	_op .4byte [llength $_debug_names_tus] "Local_type_unit_count"
 	_op .4byte 0 "Foreign_type_unit_count"
 
 	# Header - bucket count.
@@ -3037,7 +3051,15 @@ namespace eval Dwarf {
 	}
 
 	# List of Local TUs.
-	#
+	set comment "TU offset"
+	foreach tu $_debug_names_tus {
+	    upvar $tu tmp
+	    if { $is_64 } {
+		_op .8byte $tmp $comment
+	    } else {
+		_op .4byte $tmp $comment
+	    }
+	}
 
 	# List of Foreign TUs.
 	#
@@ -3087,9 +3109,20 @@ namespace eval Dwarf {
 	foreach idx $_debug_names {
 	    set name [lindex $idx 0]
 	    set tag [lindex $idx 1]
+	    set cu [lindex $idx 2]
+
+	    set cu_index [lsearch -exact $_debug_names_cus $cu]
+	    if { $cu_index == -1 } {
+		set attr_name type_unit
+		set attr_val 2
+	    } else {
+		set attr_name compile_unit
+		set attr_val 1
+	    }
+
 	    _op .byte $abbrev "abbrev $abbrev"
 	    _op .uleb128 $_constants(DW_TAG_$tag) "DW_TAG_$tag"
-	    _op .byte 1  "DW_IDX_compile_unit (attribute)"
+	    _op .byte $attr_val  "DW_IDX_$attr_name (attribute)"
 	    _op .byte 0x0f "DW_FORM_udata (form)"
 	    _op .byte 0  "abbrev terminator (attribute)"
 	    _op .byte 0  "abbrev terminator (form)"
@@ -3105,17 +3138,16 @@ namespace eval Dwarf {
 	    set cu [lindex $idx 2]
 	    set label [lindex $idx 4]
 
-	    set cu_index 0
+	    set cu_index [lsearch -exact $_debug_names_cus $cu]
-	    foreach idx2 $_debug_names_cus {
+	    if { $cu_index == -1 } {
-		if { $idx2 == $cu } {
+		set cu_index [lsearch -exact $_debug_names_tus $cu]
-		    break
+		set comment "$name: TU index"
+	    } else {
+		set comment "$name: CU index"
 	    }
-		incr cu_index
-	    }
-
 	    define_label $label
 	    _op .byte $abbrev "$name: abbrev"
-	    _op .uleb128 $cu_index "$name: CU index"
+	    _op .uleb128 $cu_index $comment
 	    _op .byte 0 "$name: terminator"
 	    incr abbrev
 	}